VBBD_Ejercicio 16_EditorTexto con RTF

' Codigo Ejercicio 16 - Editor Texto con RTF


Option Explicit


Const FILTRO_EXTENSIONES As String = "Archivos de texto (txt)|*.txt|" & _
                                     "Rich Text Formato (RTF)|*.rtf|" & _
                                     "Archivos INI|*.ini|Archivos HTML|" & _
                                     "*.htm|Todos los archivos|*.*"

Private Sub Iniciar()
Dim i As Integer

    'Acomodamos el primer botón en la esquina superior izquierda
    cmdOpcion(0).Move 50, 10, 1000, 250

    For i = 1 To 10
        Load cmdOpcion(i)
        cmdOpcion(i).Visible = True
    Next

    'Caption de los CommandButton para las opciones
    With cmdOpcion
        .Item(0).Caption = "Nuevo"
        .Item(1).Caption = "Abrir"
        .Item(2).Caption = "Guardar"
        .Item(3).Caption = "Cortar"
        .Item(4).Caption = "Copiar"
        .Item(5).Caption = "Pegar"
        .Item(6).Caption = "Bold"
        .Item(7).Caption = "Italic"
        .Item(8).Caption = "Underlined"
        .Item(9).Caption = "Imprimir"
        .Item(10).Caption = "Color"
    End With

    ' Va posicionando un botón al lado del otro
    For i = 1 To cmdOpcion.Count - 1
        cmdOpcion(i).Move cmdOpcion(i - 1).Width * i, 10, 1000, 250
    Next
End Sub

Private Sub cmdOpcion_Click(Index As Integer)
On Error GoTo men

Dim ret As VbMsgBoxResult, cnt As Long

Select Case Index
' crear un Nuevo archivo
'''''''''''''''''''''''''
  Case 0
       ret = MsgBox("Guardar el archivo?", vbQuestion + vbYesNo, App.Title)
            If ret = vbYes Then
                RichTextBox.Text = ""
                'guardamos el archivo
                GuardarArchivo
             End If
       'Limpiamos el RichTextBox
       RichTextBox.Text = ""

'Para Abrir un Archivo con el CommonDialog
'''''''''''''''''''''''''''''''''''''''''''''
  Case 1
       Call Abrir_Archivo
'Para Guardar un Archivo
'''''''''''''''''''''''''''
  Case 2
       Call GuardarArchivo
'Opción Para cortar el Texto del RichTexBox Seleccionado
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
  Case 3
       'Pegamos en el portapapeles de windows con ClipBoard
       Clipboard.SetText RichTextBox.SelText
       'Eliminamos lo seleccionado en el RichTextBox
       RichTextBox.SelText = ""
'Copiar al Clipboard
'''''''''''''''''''''''''
  Case 4
       Clipboard.SetText RichTextBox.SelText
'Pegar el contenido del portapapeles en el RichTextBox
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
  Case 5
       RichTextBox.SelText = Clipboard.GetText
'Texto en negrita con la propiedad SelBold
''''''''''''''''''''''''''''''''''''''''''''
  Case 6
       RichTextBox.SelBold = Not RichTextBox.SelBold
' Aplica Italic al texto seleccionado
''''''''''''''''''''''''''''''''''''''''
  Case 7
       RichTextBox.SelItalic = Not RichTextBox.SelItalic
' Aplica Underline al texto seleccionado
'''''''''''''''''''''''''''''''''''''''''
  Case 8
       ' Texto en cursiva
       RichTextBox.SelUnderline = Not RichTextBox.SelUnderline
' Imprimir el contenido del RichTextBox
'''''''''''''''''''''''''''''''''''''''''
  Case 9
       'Titulo del diálogo Imprimir
       CommonDialog.DialogTitle = "Seleccionar impresora"
        ' Abre el commondialog para seleccionar impresora
       CommonDialog.ShowPrinter
       ' imprimimos el archivo
       RichTextBox.SelPrint CommonDialog.PrinterDefault, rtfText

'Color del texto
''''''''''''''''''''''
  Case 10
      On Error Resume Next
      CommonDialog.DialogTitle = "Seleccionar color para el texto"
       'Abrimos el commondialog
      CommonDialog.ShowColor
       'Establecemos el color en el Texto seleccionado del RichTextBox
      RichTextBox.SelColor = CommonDialog.Color
End Select

Exit Sub
men:
    If Err.Number = 424 Then Resume Next
End Sub

'*   Subrutia para guardar el archivo en disco
'''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub GuardarArchivo()

  'Titulo del cuadro de diálogo y otras opciones
  With CommonDialog
      .DialogTitle = "Guardar Archivo"
      .Filter = FILTRO_EXTENSIONES

      'Abre el Common Dialog guardar
      .ShowSave
      If .FileName = "" Then Exit Sub
        If .FilterIndex = 2 Then
            RichTextBox.SaveFile .FileName
        Else
            RichTextBox.SaveFile .FileName, rtfText
      End If
   End With
End Sub

'* Sub para Abrir un archivo del disco
'''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub Abrir_Archivo()
  Dim ret As VbMsgBoxResult

  If RichTextBox <> "" Then
     ret = MsgBox(" Guardar el archivo ?", vbQuestion + vbYesNo, App.Title)
     'Si elegimos si, entonces guardamos el archivo
     If ret = vbYes Then GuardarArchivo
  End If

  With CommonDialog
      .DialogTitle = "Abrir Archivo"
      ' Extenciones del Commondialog
      .Filter = FILTRO_EXTENSIONES
      ' Abrimos el Commondialog
      .ShowOpen
      If .FileName = "" Then Exit Sub 'Si es un vbNullstring salimos
      ' Cargamos el fichero en el RichTextBox con el método LoadFile
      RichTextBox.LoadFile .FileName

  End With
End Sub


Private Sub Form_Load()
Call Iniciar
End Sub

Private Sub Form_Resize()
    'Redimensionamos el control RichTextBox al tamaño _
    del formulario usando el método Move del mismo.
    RichTextBox.Move 0, cmdOpcion(0).Top + cmdOpcion(0).Height, _
                     ScaleWidth, ScaleHeight

End Sub