brute force Caesar Cipher Perl

#!/usr/bin/perl

#brute force Caesar Cipher.
#The script uses a score based system, The score is incremented based on the frequency of the shifted character in the English language and an additional score is given to vowels, the highest score is the returned string which is most likely to be decrypted.

#pretty simple

use strict;
use warnings;

my $cipher_text = "ozxy fstymjw ujwq lnwq";
my $decoded_text = brute_force_caesar($cipher_text);
print "Decoded text: $decoded_text\n";

sub brute_force_caesar {
    my ($encrypted_text) = @_;
    my $decrypted_text;
    my $max_score = 0;
    my $vowel_score = 0.5;
    my $shift;
    my %letter_freq = (
        a => 8.12, b => 1.49, c => 2.71, d => 4.32, e => 12.02,
        f => 2.3, g => 2.03, h => 5.92, i => 7.31, j => 0.1,
        k => 0.69, l => 3.98, m => 2.61, n => 6.95, o => 7.68,
        p => 1.82, q => 0.11, r => 6.02, s => 6.28, t => 9.1,
        u => 2.88, v => 1.11, w => 2.09, x => 0.17, y => 2.11, z => 0.07
    );

for $shift (0..25) {
    my ($score, $shifted_text) = (0, "");
    for my $char (split //, $encrypted_text) {
        if ($char =~ /[a-z]/i) {
            my $shifted_char = chr(((ord(lc $char) - 97 + $shift) % 26) + 97);
            $shifted_text .= $char =~ /[a-z]/ ? $shifted_char : uc $shifted_char;
            $score += ($letter_freq{lc $shifted_char} // 0) + ($vowel_score * ($shifted_char =~ /[aeiou]/));
        } else {
            $shifted_text .= $char;
        }
    }


    ($max_score, $decrypted_text) = ($score, $shifted_text) if $score > $max_score;

}

    return $decrypted_text;
}