Dota2_export_to_test_client

@echo off &TITLE  Dota 2 - export settings to Test Client by AveYo
setlocal &call :set_game_profile
if not defined profile echo Error! Cannot find Dota 2 user profile &pause &exit /b

:: dota 2 beta\game\dota\cfg > dota 2 test\game\dota\cfg
xcopy /E/C/I/Q/H/R/K/Y/Z "%game%\dota\cfg\*.*" "%game_t%\dota\cfg\" >nul 2>nul
:: 570\remote > 205790\remote
xcopy /E/C/I/Q/H/R/K/Y/Z "%profile%\570\remote\*.*" "%profile%\205790\remote\" >nul 2>nul

echo  DONE! &ping localhost >nul 2>&1 &endlocal &exit /b
:set_game_profile
for /f "usebackq tokens=2* delims=_" %%A in (`reg query "HKCU\SOFTWARE\Valve\Steam" 2^>nul ^| find /i "SteamPath"`) do set "steampath=%%~A"
set "steampath=%steampath:~6%" &set "libfilter=LibraryFolders { TimeNextStatsReport ContentStatsID }"
for /f usebackq^ delims^=^"^ tokens^=4 %%A in (`findstr /v "%libfilter%" "%steampath%\SteamApps\libraryfolders.vdf"`) do (
if exist "%%A\steamapps\appmanifest_205790.acf" if exist "%%A\steamapps\common\dota 2 test\game\dota\maps\dota.vpk" set "libpath_t=%%A"
if exist "%%A\steamapps\appmanifest_570.acf" if exist "%%A\steamapps\common\dota 2 beta\game\dota\maps\dota.vpk" set "libpath=%%A")
if defined libpath_t (set "game_t=%libpath_t%\steamapps\common\dota 2 test\game") else set "game_t=%steampath%\steamapps\common\dota 2 test\game"
if defined libpath (set "game=%libpath%\steamapps\common\dota 2 beta\game") else set "game=%steampath%\steamapps\common\dota 2 beta\game"
cd /d "%game%\dota\" >nul 2>&1
for /f delims^=^ eol^= %%b in ('dir /a:-d /b /o:d /t:w cache_*.soc 2^>nul') do set "usercache=%%~nb"
set "profile=%steampath%\userdata\%usercache:cache_=%"
if exist "%profile%\config\localconfig.vdf" goto :eof
set "profile="
endlocal &goto :eof