Generatore_fasi_lunari

5 rem generatore di fasi lunari
10 rem wip by felice nardella
15 rem settaggi iniziali
20 gosub490:goto40
25 rem calcolo raggio
30 r=int(sqr(x^2+y^2)+.5):return
35 rem routine 1
40 gosub470:print"{white}{clear}"spc(15)"luna nuova"
45 pokev+21,1
50 for y=-10 to 10
55 a$=""
60 for x=-10 to 10
65 gosub30
70 if r=10 then a$=a$+"#"
75 if r-10 then a$=a$+"."
80 next
85 gosub415
90 next
95 rem routine 2
100 gosub460:print"{clear}"spc(12)"luna crescente"
105 pokev+21,1
110 for y=-10 to 10
115 a$=""
120 for x=0 to 10
125 gosub30
130 if r=10 then a$=a$+"#"
135 if r=9andx>1 then a$=a$+"#"
140 if r<9 then a$=a$+"."
145 next
150 gosub415
155 next
160 rem routine 3
165 gosub460:print"{clear}"spc(12)"primo quarto"
170 pokev+21,1
175 for y=-10 to 10
180 a$=""
185 for x=0 to 10
190 gosub30
195 if r<=10 then a$=a$+"#"
200 next
205 gosub415
210 next
215 rem routine 4
220 gosub460:print"{clear}"spc(15)"luna piena"
225 pokev+21,1
230 for y=-10 to 10
235 a$=""
240 for x=-10 to 10
245 gosub30
250 if r<=10 then a$=a$+"#"
255 if r>10 then a$=a$+"."
260 next
265 gosub415
270 next
275 rem routine 5
280 gosub460:print"{clear}"spc(13)"ultimo quarto"
285 pokev+21,1
290 for y=-10 to 10
295 a$=""
300 for x=-10 to 0
305 gosub30
310 if r<=10 then a$=a$+"#"
315 if r>10 then a$=a$+"."
320 next
325 gosub415
330 next
335 rem routine 6
340 gosub460:print"{clear}"spc(14)"luna calante"
345 pokev+21,1
350 for y=-10 to 10
355 a$=""
360 for x=-10 to 0
365 gosub30
370 if r=10 then a$=a$+"#"
375 if r=9andx<-1 then a$=a$+"#"
380 if r>10 then a$=a$+"."
385 next
390 gosub415
395 next
400 rem loop
405 gosub460:goto40
410 rem calcolo pixel sprite
415 for k=0 to 2
420 t=0
425 for j=0 to 7
430 b=0:if mid$(a$,j+k*8+1,1)="#" then b=1
435 t=t+b*tw(7-j):next
440 poke704+(y+10)*3+k,t
445 next
450 return
455 rem disattiva e cancella sprite
460 printtab(255)tab(255)tab(255)spc(5)"premi un tasto..."
465 poke198,0:wait198,1
470 pokev+21,0
475 for n=704 to 767:poke n,0: next
480 return
485 rem settaggi preliminari sprite
490 print"{clear}":v=53248:pokev+32,0:pokev+33,0
495 poke2040,11: pokev,160: pokev+1,100:rem pointer; x,y
500 pokev+29,1: pokev+23,1:rem expansion x,y
505 pokev+39,7: rem color
510 tw(0)=1:fori=1to7:tw(i)=tw(i-1)*2:next
515 return