C16-graph&Sound

10 graphic 3,1
20 color 0,1
30 color 4,1
40 color 1,2
50 color 2,2,4
60 color 3,2,4
65 vol 8: f=1000: rem volume e frequenza
70 t=1: rem y dove mettere la stella
80 s=0: rem status, indica in che fase del disegnosi sta lavorando
81 sa=1:ea=10:xp=0:yp=0:xn=0:yn=0: rem start angle, end angle
90 if  s = 0 then goto 1000 : rem gestione cielo stellato
100 if s = 1 then goto 2000 : rem gestione cerchio principale
899 rem gestione suono
900 if s > 1 then goto 9000: rem se finita ultima fase allora esci
910 sound 1, f, 2
920 f=f-1:if f<700 then f=1000
990 goto 90

999  rem visualizzazione random delle stelle
1000 draw 1,rnd(1) * 160,t
1010 t=t+1
1020 if t > 200 then s=s+1: rem se ultima riga allora passa alla fase successiva del disegno
1030 goto 900 : rem gestione suono

1999 rem visualizzazione del cerchio con 36 archi progressivi da 10 gradi ognuno
2000 circle 2,80,100,30,,sa,ea: xn = rdot(0): yn=rdot(1):draw 2, 80,100 to xn, yn
2005 if xp <> 0 then draw 2, 80,100 to xp, yp:circle 1,80,100,15,,sa,ea-5:paint 2, rdot(0), rdot(1)
2008 xp = xn : yp =yn
2010 sa = sa+10: ea=ea+10: if ea > 360 then s=s+1: circle 1,80,100,15,,0,5:paint 2, rdot(0), rdot(1) : rem passa alla fase successiva
2020 goto 900




8999 rem uscita
9000 vol 0
9010 end