Begin ssh_launch

float timer
short state

if ( menumode == 1 )
	return
endif

if ( state == 0 )

	PlayBink, "shhLaunchLR.bik", 0
	FadeOut, 0.1
	set state to 20

	; endif ; fixed /abot

elseif ( state == 20 )

	set timer to ( timer + GetSecondsPassed )

	if ( timer >= 2.0 )
		set timer to 0
		set state to 100
		FadeIn, 1.0
		stopscript ssh_launch
	endif

endif

end


Begin ssh_crash

float timer
short state

if ( menumode == 1 )
	return
endif

if ( state == 0 )
	PlaySound VD_crash
	FadeOut 1.0
	set state to 20
	SHH_Centurion_Worker->SetFight, 100
	"SHH_Centurion_Worker"->StartCombat Player
	SHH_Centurion_SecurityM->SetFight, 100
	"SHH_Centurion_SecurityM"->StartCombat Player
	; endif ; fixed /abot
elseif ( state == 20 )
	set timer to ( timer + GetSecondsPassed )
	if ( timer >= 4.0 )
		Journal "SSH_Shipwrecked" 10
		set timer to 0
		set state to 100
		FadeIn 1.0
		stopscript ssh_crash
	endif
endif

end



Begin shh_seashantyscript

short songstate
float Timer
short questionAsked
short Button

if ( MenuMode )
	return
endif

if ( songstate == 9 )
	StopScript shh_seashantyscript ; [EDITED]
	return
endif

if ( songstate == 0 )
	DisablePlayerControls
	set songstate to 100
	"shh_fenrir"->Say, "Vo\SHH\To See My Systres full.mp3", "...."
endif

if ( songstate == 100 )
	set timer to timer + GetSecondsPassed
	if ( timer >= 25 )
		set songstate to 1
	endif
endif

if ( songstate == 1 )
	if ( questionAsked == 0 )
		set questionAsked to 1
		MessageBox "I hug the coast on the sea of ghosts...", "...and jumped at every whisper!", "...I was looking for my treasure!", "... but only saw my sisters!"
	elseif ( questionAsked == 1 )
		set button to GetButtonPressed
		if ( button == 0 )
			set songstate to 2
			set timer to 0
			set questionAsked to 0
		elseif ( button > 0 )
			PlaySound "crowd booing"
			set songstate to 0
			set timer to 0
			set questionAsked to 0
		endif
	endif
	return
endif

if ( songstate == 2 )
	if ( questionAsked == 0 )
		if ( "shh_fenrir"->SayDone == 1 )
			"shh_fenrir"->Say, "Vo\SHH\To See My Systres verse1.mp3", "...."
		endif
		set questionAsked to 1
	elseif ( questionAsked == 1 )
		if ( "shh_fenrir"->SayDone == 1 )
			set timer to 0
			set songstate to 3
			set questionAsked to 0
		endif
	endif
	return
endif

if ( songstate == 3 )
	if ( questionAsked == 0 )
		MessageBox, "May Kyne's fair kin get kissed 't the end...", "And drink to the daedra devils!", "That's just the way she sails!", "But I'd rather see my sisters!"
		set questionAsked to 1
	elseif ( questionAsked == 1 )
		set button to GetButtonPressed
		if ( button == 2 )
			set songstate to 4
			set timer to 0
			set questionAsked to 0
		elseif ( button < 2 )
			PlaySound, "crowd booing"
			set songstate to 0
			set timer to 0
			set questionAsked to 0
		endif
	endif
	return
endif

if ( songstate == 4 )
	if ( questionAsked == 0 )
		if ( "shh_fenrir"->SayDone == 1 )
			"shh_fenrir"->Say, "Vo\SHH\To See My Systres verse2.mp3", "...."
		endif
		set questionAsked to 1
	elseif ( questionAsked == 1 )
		if ( "shh_fenrir"->SayDone == 1 )
			set timer to 0
			set songstate to 5
			set questionAsked to 0
		endif
	endif
	return
endif

if ( songstate == 5 )
	if ( questionAsked == 0 )
		MessageBox, "So guide all hands through Dunmer lands...", "And drink back all wrong memories!", "And sing Saxhleel tongue-twisters!", "And kick that old bad daedra!"
		set questionAsked to 1
	elseif ( questionAsked == 1 )
		set button to GetButtonPressed
		if ( button == 1 )
			set songstate to 6
			set timer to 0
			set questionAsked to 0
		elseif ( button == 0 )
			PlaySound, "crowd booing"
			set songstate to 0
			set timer to 0
			set questionAsked to 0
		elseif ( button == 2 )
			PlaySound, "crowd booing"
			set songstate to 0
			set timer to 0
			set questionAsked to 0
		endif
	endif
	return
endif

if ( songstate == 6 )
	if ( questionAsked == 0 )
		if ( "shh_fenrir"->SayDone == 1 )
			"shh_fenrir"->Say, "Vo\SHH\To See My Systres verse3.mp3", "...."
		endif
		set questionAsked to 1
	elseif ( questionAsked == 1 )
		if ( "shh_fenrir"->SayDone == 1 )
			set timer to 0
			set songstate to 7
			set questionAsked to 0
		endif
	endif
	return
endif

if ( songstate == 7 )
	if ( questionAsked == 0 )
		MessageBox, "Go drink and sin in Morrowind...", "I don't think I'll miss her!", "That dog's an old raw blister!", "I'd rather see my sisters!"
		set questionAsked to 1
	elseif ( questionAsked == 1 )
		set button to GetButtonPressed
		if ( button == 2 )
			set songstate to 8
			set timer to 0
			set questionAsked to 0
		elseif ( button < 2 )
			PlaySound, "crowd booing"
			set songstate to 0
			set timer to 0
			set questionAsked to 0
		endif
	endif
	return
endif

if ( songstate == 8 )
	if ( questionAsked == 0 )
		if ( "shh_fenrir"->SayDone == 1 )
			"shh_fenrir"->Say, "Vo\SHH\To See My Systres verse4.mp3", "...."
		endif
		set questionAsked to 1
	elseif ( questionAsked == 1 )
		if ( "shh_fenrir"->SayDone == 1 )
			set timer to 0
			set songstate to 9
			set questionAsked to 0
			Journal "SHH_Captain" 80
			EnablePlayerControls
		endif
	endif
endif

end