PaiDeSanto_18B20.ino

/*
Este identifica o tipo de sensor
26/06/2015
Funciona muito Bem
 */

  #include <OneWire.h>    // Biblioteca de 1Wire
  OneWire  ds(4);        // Seleciona a porta do 1WirwBus on pin 4
  int contador = 0;
 //----------------------------------------------------------------------
  void setup()
  {
    Serial.begin(9600);   // Inicialisa a serial
    delay(1000);          //Aguarda 1 seg antes de acessar as informações do sensor
  }
 //----------------------------------------------------------------------
  void loop()
  {
    byte i;              // Variavel de uso geral
    byte present = 0;    // Variavel para present bit do 1Wire
    byte type_s;         // Variavel para selecionar o tipo de Sensor
    byte data[12];       // Matriz para guardar os dados lidos do sensor
    byte addr[8];        // Matriz para guardar endereço lidos do sensor
    float celsius, fahrenheit;   // Variavel para guardar o valor das temparutras

    if ( !ds.search(addr))       // Search for the next device.
    {
      Serial.println("No more addresses.");
      contador = 0;
      Serial.println();
      ds.reset_search();         // Begin a new search.
      delay(100);
      return;
    }
    contador++;
    Serial.print(contador);
    Serial.print("  ROM =");
    for( i = 0; i < 8; i++)     // inicia a impresão do valor da ROM
    {
      Serial.write(' ');
      Serial.print(addr[i], HEX);
    }

    if (OneWire::crc8(addr, 7) != addr[7])     // Verifica o CRC
    {
      Serial.println("CRC is not valid!");
      return;
    }
    Serial.print(" ");

    // the first ROM byte indicates which chip
    switch (addr[0])             // Le o byte 0 da ROM
    {
      case 0x10:                // Se for 0x10
        Serial.println("  Chip = DS18S20");  // or old DS1820
        type_s = 1;             // Set tipo = 1
        break;
      case 0x28:                // Se for 0x28
        Serial.println("  Chip = DS18B20");
        type_s = 0;             // Set tipo = 0
        break;
      case 0x22:                // Se for 0x22
        Serial.println("  Chip = DS1822");
        type_s = 0;             // Set tipo = 0
        break;
      default:
        Serial.println("Device is not a DS18x20 family device.");
        return;
    }

    ds.reset();                // Reset the 1-wire bus.
    ds.select(addr);           // Select a device based on its address.
    ds.write(0x44,1);          // start conversion, with parasite power on at the end

    delay(1000);               // maybe 750ms is enough, maybe not
    // we might do a ds.depower() here, but the reset will take care of it.

    present = ds.reset();      // Reset the 1-wire bus. e agurada o Present Pulse
    ds.select(addr);           // Select a device based on its address.
    ds.write(0xBE);            // Read Scratchpad

    Serial.print("  Data = ");
    Serial.print(present,HEX);
    Serial.print(" ");
    for ( i = 0; i < 9; i++)   // Imprime os 8 bytes de dados
    {           // we need 9 bytes
      data[i] = ds.read();     // Read a byte.
      Serial.print(data[i], HEX);
      Serial.print(" ");
    }
    Serial.print(" CRC=");
    Serial.print(OneWire::crc8(data, 8), HEX);  // Imprime o CRC8
    Serial.println();

    // convert the data to actual temperature

    unsigned int raw = (data[1] << 8) | data[0]; // Função raw  Shift Data[1] 8 bits
                                                 //   e faz or com data[0]
    if (type_s)
    {
      raw = raw << 3; // 9 bit resolution default
      if (data[7] == 0x10)
      {
        // count remain gives full 12 bit resolution
        raw = (raw & 0xFFF0) + 12 - data[6];
      }
    }
    else
    {
      byte cfg = (data[4] & 0x60);
      if (cfg == 0x00) raw = raw << 3;  // 9 bit resolution, 93.75 ms
      else if (cfg == 0x20) raw = raw << 2; // 10 bit res, 187.5 ms
      else if (cfg == 0x40) raw = raw << 1; // 11 bit res, 375 ms
      // default is 12 bit resolution, 750 ms conversion time
    }
    celsius = (float)raw / 16.0;
    fahrenheit = celsius * 1.8 + 32.0;
    Serial.print("  Temperature = ");
    Serial.print(celsius);
    Serial.print(" Celsius, ");
    Serial.print(fahrenheit);
    Serial.println(" Fahrenheit");

    //Não diminuir o valor abaixo. O ideal é a leitura a cada 2 segundos
    delay(1000);
  }