Arma 3 Map Object Duplicate Checker (Uncommented)

_handle = player call {
    private _objList = [];
    private _tempList = [];
    private _resultsList = [];
    private _nearList = [];
    private _primeHouse;
    private _dst = 1;
    private _markerCount = 0;
    private _type = "All";
    _objList = [0,0,0] nearObjects [_type, worldsize*2];
    _objList = _objList select
    {   _objType = toLower typeOf _x;
    ///////   BLACKLIST  /////////
        !("land_hutch_01_f" in _objType) && // beehive
        !("light" in _objType) && // all lights
        !("wall" in _objType) &&
        !("fence" in _objType) &&
        !("fuel" in _objType) && // gas pumps
        !("fs_feed" in _objType) && // gas pumps again
        !("stairs" in _objType) &&
        !("ramp" in _objType) &&
        !("powerline" in _objType) && // WICHTIG
        !("grave" in _objType) &&
        !("kontejner" in _objType) && // dumpster
        !("corner" in _objType) &&
        !("balik" in _objType) && // hay bale
        !("shed_04" in _objType) &&
        !("airshaft" in _objType) &&
        !("toilet" in _objType) &&
        !("misc_cargo" in _objType) && // cargo containers
        !("targetp" in _objType) && // practice targets
        !("chickencoop" in _objType) &&
        !("fx" in _objType) // effects
    ///////   BLACKLIST  /////////
    };

    {   _primeHouse = _x;
        _primePos = position _primeHouse;
        _primeType = typeOf _primeHouse;
        if (_primeType isKindOf "House") then {_dst = 3} else {_dst = 1};
        _nearList = _primePos nearObjects [_primeType, _dst] select {!(_x isEqualTo _primeHouse) && (_x isKindof _PrimeType)};
        _nearListCount = count _nearList;
        _markers = allMapMarkers select {((getMarkerPos _x vectorDistance _primePos) < 1)};

        if  ((_nearListCount > 0) && (count _markers == 0)) then
        {   _markerCount = _markerCount + 1;
            _marker = createMarker [str _markerCount, position _x];
            _marker setMarkerType "hd_warning";
            _marker setMarkerColor "ColorRed";
            _marker setMarkerText (str _markerCount + " " + str (typeOf _x));
            _tempList = [];
            _tempList append [_markerCount];
            {_tempList append [typeOf _x, getPos _x]} forEach _nearList;
            _resultsList append [_tempList];
        };
    } forEach _objList;

    {diag_log _x} forEach _resultsList;
};